The trouble with getBounds()

function getVisibility(obj:DisplayObject):Rectangle {
 
	var vis:Rectangle;
 
	if (obj.parent == null) return new Rectangle();
 
	if (obj is DisplayObjectContainer) {
		vis = getChildVisibility(obj, obj.parent);
	} else {
		vis = obj.getBounds(obj.parent);
	}
 
	// Is the DisplayObject masked?
	if (obj.mask != null) {
		vis = vis.intersection(obj.mask.getBounds(obj.parent));
	}
 
	// Is the DisplayObject partly or completely off-stage?
	vis = vis.intersection(obj.stage.getBounds(obj.parent));
 
	return vis;
}
 
function getChildVisibility(obj:*, target:DisplayObjectContainer):Rectangle {
 
	var vis:Rectangle = new Rectangle();
	var child:DisplayObject;
	var childRect:Rectangle;
	var i:uint;
 
	for (i = 1; i <= obj.numChildren; i++) {
		child = obj.getChildAt(i-1);
 
		if (child != null) {
			if (child.visible) {
				if (child is DisplayObjectContainer) {
					childRect = getChildVisibility(child, target);
				} else {
					childRect = child.getBounds(target);
				}
				if (child.mask != null) {
					childRect = childRect.intersection(child.mask.getBounds(target));
				}
				vis = vis.union(childRect);
			}
		}
	}
	return vis;
}

6 Comments »

• colin

  hey david,
  you could use a bitmap to check the real dimensions. too bad actionscript doesn’t provide something built-in. here’s a simple example:

  package {
    import flash.display.*;
    import flash.geom.ColorTransform;
    import flash.geom.Rectangle;
    import flash.text.TextField;
   
    public class Test extends Sprite {
      private var t:TextField;
      private var m:Shape;
   
      public function Test () {
        t = new TextField();
        t.background = true;
        t.backgroundColor = 0x00FF00;
        t.text = "Hi there";
   
        m = new Shape();
        m.graphics.beginFill(0x000000);
        m.graphics.drawRect(0, 0, 15, 25);
   
        addChild(t);
        addChild(m);
        t.mask = m;
   
        trace(t.height);  // 100 (not 25)
        trace(getVisibleHeight(t));
      }
   
      public function getVisibleHeight (o:DisplayObject):Number {
        var bounds:Rectangle;
        var bitmapData:BitmapData = new BitmapData(o.width, o.height, true, 0);
        bitmapData.draw(o, null, new ColorTransform( 1, 1, 1, 1, 255, -255, -255, 255 ) );
        bounds = bitmapData.getColorBoundsRect( 0xFF000000, 0xFF000000 );
        bitmapData.dispose(); 
        return bounds.y + bounds.height;
      }
    }
  }

  Comment | 9.Nov.08
• barliesque

  Thanks for dropping by Colin.

  That’s an approach to the problem I hadn’t considered. Looks like a pretty reliable method without the problem of having to reconstruct masks in code. Nice! I only wonder if the performance hit of pre-rendering the MovieClip makes it usable on a frame-by-frame basis.

  Comment | 10.Nov.08
• matt

  this saved me a lot of time and frustration, thanks David!

  Comment | 15.Oct.09
• getBounds() on DisplayObject not functioning properly | Down the Rabbit Hole

  [...] During my search, I found a post from David Barlia: http://studio.barliesque.com/blog/2008/10/the-trouble-with-getbounds/ [...]

  Pingback | 26.Jan.10
• Thomas

  Hi,
  tkx for your code.
  I took the BitmapData approach from colin and made a function that works with DisplayObject whose upper left corner is not at 0,0. It returns a Rectangle object too.

  http://blog.open-design.be/2010/01/26/getbounds-on-displayobject-not-functioning-properly/

  Comment | 26.Jan.10
• y_nk

  hello,

  i tried this with 2 squares named “test” and “masque” in the IDE :

  test.mask = masque;
  test.scrollRect = new Rectangle(0, 0, 20, 20);

  var real:Rectangle;

  real = test.getRect(test)
  .intersection(test.mask.getRect(test))
  .intersection(test.scrollRect);

  trace(real); (x=10, y=10, w=10, h=10)

  i don’t know if it looks like what you want

  Comment | 22.Apr.10

RSS feed for comments on this post. TrackBack URL

Leave a comment!